Groovy switch magic

Рассмотрим такой простой и тривиальный оператор, как switch. Казалось бы, ну что можно придумать нового вокруг него? Ан-нет, можно.


В Java как известно, switch-ить можно только по целым числам и по Enum-ам, и все это жестко зашито в синтаксисе языка. Остальное - запрещено. В Groovy же этот оператор работает следующим образом.


Общая логика работы оператора switch проста и знакома каждому программисту:

switch (candidate) {
  case classifier1 : handle1() ; break
  case classifier2 : handle2() ; break
  default : handleDefault()
}

А теперь надо вспомнить, что в Groovy, в отличие от Java, "все есть объект". Т.е. абсолютно все, без исключений в виде примитивных типов. Соответственно, classifier1, classifier2 и candidate - объекты. И для того, чтобы вышеприведенная конструкция работала, необходимо и достаточно, чтобы classifier 1 и classifier2 имели метод isCase(candidate), возвращающий булево значение. Все просто.

И еще несколько ценных свойств свитчей в Groovy. 
Во-первых, классификаторы classifier1 и classifier2 вовсе не обязаны быть одного и того же типа. Во-вторых, выражение-candidate может удовлетворять нескольким case-ам, а не одному. Откуда следует, что порядок case-ов в Groovy, в отличие от Java,  важен.


Ну и небольшой пример, что можно делать в switch-ах в Groovy:

switch (20) {
   case 2 : assert false ; break // Равно двум?
   case 2..15 : assert false ; break // Попадает в диапазон?
   case [11,12,14,16] : assert false ; break // Входит в список?
   case Double : assert false ; break // является Double-типом?
   case {it % 5 == 0}: assert true ; break // Делится на пять?
   case ~/../ : assert true; break // В эту ветку мы не заходим
   default : assert false ; break
}